Data Analysis Expressions (DAX)

In the Tabular BI Semantic Model

SQL Server Technical Article

**Authors:** Howie Dickerman, Peter Myers

**Contributors:** Kasper de Jonge, Owen Duncan

**Published:** December 2011

**Applies to:** PowerPivot, SQL Server 2012 Analysis Services

**Summary:** This paper introduces Data Analysis Expressions (DAX), a formula expression language used to define calculations in PowerPivot for Excel® workbooks and tabular model projects authored in SQL Server Data Tools. DAX functions provide extensive filtering to calculate on data across multiple tables, work with relationships, and perform dynamic aggregation. DAX formulas use the highly optimized in-memory engine to rapidly query and calculate values from very large data sets.

The concepts introduced in this paper will help you in learning DAX and how you can use DAX formulas effectively to solve real-world business problems and meet the Business Intelligence needs of your organization.

# ****Copyright****

The information contained in this document represents the current view of Microsoft Corporation on the issues discussed as of the date of publication. Because Microsoft must respond to changing market conditions, it should not be interpreted to be a commitment on the part of Microsoft, and Microsoft cannot guarantee the accuracy of any information presented after the date of publication.

This White Paper is for informational purposes only. MICROSOFT MAKES NO WARRANTIES, EXPRESS, IMPLIED OR STATUTORY, AS TO THE INFORMATION IN THIS DOCUMENT.

Complying with all applicable copyright laws is the responsibility of the user. Without limiting the rights under copyright, no part of this document may be reproduced, stored in or introduced into a retrieval system, or transmitted in any form or by any means (electronic, mechanical, photocopying, recording, or otherwise), or for any purpose, without the express written permission of Microsoft Corporation.

Microsoft may have patents, patent applications, trademarks, copyrights, or other intellectual property rights covering subject matter in this document. Except as expressly provided in any written license agreement from Microsoft, the furnishing of this document does not give you any license to these patents, trademarks, copyrights, or other intellectual property.

Unless otherwise noted, the companies, organizations, products, domain names, e-mail addresses, logos, people, places, and events depicted in examples herein are fictitious. No association with any real company, organization, product, domain name, e-mail address, logo, person, place, or event is intended or should be inferred.

 2011 Microsoft Corporation. All rights reserved.

Microsoft, Excel, PowerPivot are trademarks of the Microsoft group of companies.

All other trademarks are property of their respective owners.

Table of Contents

[Copyright 2](#_Toc312154773)

[Executive Summary 5](#_Toc312154774)

[Samples 6](#_Toc312154775)

[Companion Workbook 6](#_Toc312154776)

[Contoso Dataset 6](#_Toc312154777)

[Data Analysis Expressions (DAX) – The Basics 8](#_Toc312154778)

[DAX Goals 8](#_Toc312154779)

[DAX Calculations - Calculated Columns and Measures 8](#_Toc312154780)

[DAX Syntax 13](#_Toc312154781)

[DAX Uses Tabular Model Data Types 14](#_Toc312154782)

[Intro to Context – Row Context and Filter Context 14](#_Toc312154783)

[Functionality That Does Not Exist In Excel Formulas 15](#_Toc312154784)

[DAX Operators and Constants 16](#_Toc312154785)

[Simple DAX Functions 17](#_Toc312154786)

[BLANK() and Blank Values 17](#_Toc312154787)

[Functions from Excel 18](#_Toc312154788)

[FORMAT(Value, Format\_text) 19](#_Toc312154789)

[Functions to Aggregate Expressions – the “X” Functions 19](#_Toc312154790)

[COUNTROWS(Table) 20](#_Toc312154791)

[RELATED(Column) and RELATEDTABLE(Table) 20](#_Toc312154792)

[USERELATIONSHIP(Column1, Column2) 23](#_Toc312154793)

[FILTER(Table, Condition) and DISTINCT (Column) 23](#_Toc312154794)

[Row Context and Filter Context 24](#_Toc312154795)

[Row Context 24](#_Toc312154796)

[Filter Context 25](#_Toc312154797)

[Relationships and Filter Context 26](#_Toc312154798)

[Measures and Filter Context 27](#_Toc312154799)

[More DAX Functions 28](#_Toc312154800)

[CALCULATE(Expression, SetFilter1, SetFilter2,...) 28](#_Toc312154801)

[VALUES(Column) 32](#_Toc312154802)

[CALCULATETABLE(TableExpression, SetFilter1, SetFilter2,...) 34](#_Toc312154803)

[ALL(Table) and ALL(Column1 [,Column2]...) 34](#_Toc312154804)

[ALLEXCEPT(Table [,Column1] [,Column2]...) 36](#_Toc312154805)

[RANKX(Table, Expression [,Value] [,Order] [,Ties]…) 36](#_Toc312154806)

[RANK.EQ(Value, ColumnName [,Order]) 38](#_Toc312154807)

[TOPN(N\_Value, Table [,OrderBy\_Expression1] [,Order1] [,OrderBy\_Expression2] [,Order2]…) 39](#_Toc312154808)

[LOOKUPVALUE(Result\_ColumnName, Search\_ColumnName1, Search\_Value1 [,Search\_ColumnName2] [,Search\_\_Value2]…) 40](#_Toc312154809)

[ALLSELECTED() 40](#_Toc312154810)

[Time Intelligence Functions 41](#_Toc312154811)

[Concepts and Best Practices 41](#_Toc312154812)

[Functions that Return a Single Date 43](#_Toc312154813)

[Functions that Return a Table of Dates 48](#_Toc312154814)

[Year Over Year Growth 49](#_Toc312154815)

[Calculating Many Time Periods Within a Single Measure Formula 51](#_Toc312154816)

[Functions that Evaluate Expressions Over a Time Period 56](#_Toc312154817)

[Parent-Child Functions 57](#_Toc312154818)

[Sample Formulas 63](#_Toc312154819)

[Calculated Columns 63](#_Toc312154820)

[Measures 64](#_Toc312154821)

[DAX Query 64](#_Toc312154822)

[Additional Resources 69](#_Toc312154823)

# Executive Summary

With the release of Microsoft SQL Server 2012, Analysis Services introduces a new paradigm in Business Intelligence data modeling, the BI Semantic Model (BISM). BISM includes both traditional multidimensional models developed by BI professionals and deployed to Analysis Services, and the new Tabular Model. There are two flavors of tabular models: PowerPivot for Excel, first introduced with SQL Server 2008 R2, provides self-service data modeling solutions, and the new Tabular Project, authored in SQL Server Data Tools (formerly known as BIDS) and deployed to Analysis Services running in Tabular server mode.

Both PowerPivot and tabular project data modeling approaches include the ability to import data from a wide variety of data sources, the ability to perform calculations on large volumes of in-memory data quickly, the ability to author custom calculations using the DAX (Data Analysis Expressions) language, and the ability to use the result of those calculations in a variety of client applications and tools, including Excel, Microsoft Power View, and Microsoft Reporting Services. Whether you choose to author tabular models by using PowerPivot or by using tabular projects in SQL Server Data Tools, the DAX language’s operators, functions, and syntax is the same.

There are millions of Microsoft Excel users who are familiar with using Excel formulas to perform calculations. Those calculations may be as simple as adding up a column of numbers, or they may be far more complex simulations of various business models. But in every case, each formula is built using a combination of basic operators and functions that are provided within Excel. Similarly, for professional BI solution developers using Multidimensional Expressions (MDX) in multidimensional model solutions, the fundamental concepts of creating calculations by using formulas is much the same; however, the differences in syntax, operators, and functions between MDX and DAX formulas is greater than it is between Excel and DAX formulas. Whether you are familiar with Excel or MDX formulas, this basic understanding of formulas is important when developing tabular data modeling solutions. While understanding Excel or MDX formulas will give you a head start in learning DAX, it is not necessary.

DAX formulas are very similar to Excel formulas, and there is considerable overlap between the list of DAX functions and Excel functions. But there are also significant differences, and many new functions in DAX that don’t exist within Excel. These functions are designed to offer capabilities that focus on data analysis, particularly for related tables of data, and for dynamic analysis.

This paper outlines the use of DAX formulas in tabular BI Semantic Models, in-particular PowerPivot for Excel, and describes the many DAX functions (including many new ones) supported in tabular model solutions. In addition to describing the functions themselves, there is a discussion of the important concepts that any model developer will want to know. It is hoped that this paper might be a good way to become familiar with the basics of the DAX formula language.

If you are authoring tabular model solutions by using the tabular model project templates in SQL Server Data Tools, the DAX concepts, syntax, functions, and formulas described here apply much the same; only the tools user interface and the ability to use DAX formulas in row-level security for Roles is different.

# Samples

## Companion Workbook


DAX formulas described in this document are included in the Contoso Sample DAX Formulas PowerPivot workbook available on Microsoft Download Center: <http://go.microsoft.com/fwlink/?LinkID=237472&clcid=0x409>

## Contoso Dataset

The samples used as illustrations in this document all come from an Excel workbook that imported its relational data from the “Contoso” SQL Server relational database that is available from the Microsoft Download Center as part of Microsoft Contoso BI Demo Dataset for Retail Industry:

<http://www.microsoft.com/download/en/details.aspx?displaylang=en&id=18279>

To build the sample workbook, data is imported from eleven (11) of the tables in the Contoso database:



There are two tables of transactions in this data: FactSales and FactInventory. (This explains why the samples in this paper illustrate Sales and/or Inventory scenarios.) Eight tables are related to one or both of the transaction (fact) tables as shown in the diagram above.

The DimEmployee table is stand alone and is used solely to illustrate the parent-child DAX functions.

This sample data set contains approximately 3.4 million sales transactions and more than 8 million inventory transactions. When loaded into an Excel workbook using PowerPivot, it illustrates two very compelling advantages of PowerPivot for data analysis over simple Excel PivotTables in Excel:

* The ability to base a PivotTable on a set of multiple tables (as opposed to a single flattened table).
* The ability to consume far larger data volumes (more rows) than can fit within an Excel worksheet.

# Data Analysis Expressions (DAX) – The Basics

## DAX Goals

The goal of tabular models is to make data analysis really easy, and in doing so, expand data modeling to more users. The idea is that Excel users and IT professionals should be able to leverage the training and experience they already have and should not be required to learn complex multidimensional concepts nor specialized multidimensional languages like MDX.

With this in mind, DAX was created to achieve the following:


* Ease-Of-Use DAX uses standard Excel formula syntax (and some of Excel’s functions)
* Relational Data Simple relational data model based on tables, columns, and relationships
* PivotTables Analysis performed via PivotTables based on the database (multiple tables)

## DAX Calculations - Calculated Columns and Measures


A DAX formula is used to define a field that will be placed somewhere on an Excel PivotTable. There are two types of fields that can be placed on a PivotTable: **columns** and **measures**.

**Calculated Columns** are columns that are defined in the PowerPivot Window by providing a column name and a DAX expression. Calculated Columns are populated with values when they are defined and become just like any other column in a table, except that regular (non-calculated) columns are usually imported from an external data source while calculated columns are calculated after the regular columns have been loaded. The values from a column may be placed onto a PivotTable’s row labels or column labels or may be placed in a PivotTable’s filter/slicer to control the portion of the data that will be used in the analysis. Finally a column may be used as part of the calculation that defines a measure (described below). Here are a couple of simple calculated columns:

1. [Margin] defined as: =[SalesAmount]-[TotalCost]




1. [CityState]defined as: =[CityName]&", " & [StateProvinceName]




**Measures** are named formulas that are defined in the PowerPivot Window’s Measure Grid, or in Excel, they can also be defined in the PowerPivot Field List (in the Excel window, while focus is on a PivotTable.) Once defined, measures can be added to the Values area of the PivotTable. The formula is evaluated when the measure is placed into the Values area of an Excel PivotTable and then it is evaluated separately for each cell in the Values area. Here are a couple of Measure definitions:

* [Sales] defined as: =SUM(FactSales[SalesAmount])



* [Average Sale] defined as: =AVERAGE(FactSales[SalesAmount])



Here’s what you get when you add these two measures to a PivotTable with Calendar Year on Row Labels. Observe how we get four results for each measure – one per year plus a total for all years.


|  |  |  |
| --- | --- | --- |
| **Row Labels** | **Sales** | **Average Sale** |
| 2007 | $4,561,940,955.02 | $3,103.94 |
| 2008 | $4,111,233,534.68 | $3,909.73 |
| 2009 | $3,740,483,119.18 | $4,227.38 |
| **Grand Total** | **$12,413,657,608.89** | **$3,644.55** |

In addition to DAX measures that are defined by a DAX formula, the tabular model also provides a simpler way to define measures when all you want to do is take a column and aggregate it. This is known as an implicit measure. You can easily build implicit measures that calculate the SUM, COUNT, MIN, MAX, AVERAGE or DISCOUNTCOUNT of a column using checkboxes and dropdowns in the PowerPivot Field List in Excel. So while it is easy to create a measure that is merely the SUM, COUNT, MIN, MAX, AVERAGE or DISTINCTCOUNT of a column, you can perform calculations that are far more powerful using DAX formulas instead of the six built in aggregations.

To illustrate this, consider the PivotTable shown below. There are two measures in this PivotTable that show precisely the same results. One (named Sales) uses a DAX formula, (as illustrated above) while the other one (named Sum of Sales Amount) does not.

|  |  |  |
| --- | --- | --- |
| **Row Labels** | **Sales** | **Sum of SalesAmount** |
| Catalog | $1,078,007,547.23 | $1,078,007,547.23 |
| Online | $2,677,599,035.07 | $2,677,599,035.07 |
| Reseller | $1,715,197,831.44 | $1,715,197,831.44 |
| Store | $6,942,853,195.14 | $6,942,853,195.14 |
| **Grand Total** | **$12,413,657,608.89** | **$12,413,657,608.89** |

The Measure Settings dialog window for the measure “Sum of SalesAmount” shows that this measure was defined by simply checking the SalesAmount column in the field list and leaving the default aggregation as “Sum”. This dialog window is slightly different than the dialog window that appears when a measure is created using a DAX formula.



## DAX Syntax

DAX syntax mimics Excel syntax as much as possible. In particular, DAX uses function composition just as Excel does, and also refers to columns in tables using the same syntax as Excel. DAX then extends that syntax to measures as well.

**References to Columns and Measures**

The name of a column is always unique within a given table, and the name of a measure must be unique across the entire data model. Just as each column belongs to a particular table, each measure also belongs to a particular table. We mimic the syntax used by Excel for columns. When a DAX expression refers to a column or measure, the name of that column or measure must be appear within square brackets, and it will sometimes be preceded by the name of the table to which the column or measure belongs. Here are some examples:

Fully qualified names:

* Table1[Column2] as in =SUM(Table1[Column2])
* Table2[Measure1] as in = 2.5 \* Table2[Measure1]

Unqualified names:

* [Column2] as in =[Column1] + [Column2]
* [Measure2] as in =[Measure2]/[Measure3]

DAX formulas that refer to columns generally require the references be fully qualified, but an exception is made when a calculated column refers to other columns from within the same table. In these cases, the column references need not be fully qualified. Since measure names are globally unique within a model, we do not generally require measure names to be fully qualified.

Unlike Excel formulas, DAX has no notion of addressing individual cells or ranges. Notation such as B14 or C12:C15 which are valid in Excel will not work in DAX expressions. Instead, DAX always refers to a column of data by providing the (qualified or unqualified) column name. When there is a row context, this reference to a column will be interpreted as the value of that column in the current row.

***Note:*** *It is possible to create a calculated column using the same name as a measure from a different table. When this occurs, it is important to use a fully qualified reference to the column in any formula to avoid invoking the measure when the intention was to invoke the calculated column.*

**Split Measures into Separate Measures**

To make measures easier to define and maintain, when possible, it is recommended to split measures into separate measures. So instead of writing a single measure that does SUM(FactSales[SalesAmount]) / SUM(Table1[SalesQuantity]) it is recommended to create two measures, and use them in a new measure. You can hide the intermediate measures so they’re not exposed to the end users. This will improve readability, improve the ability to debug parts of the measure and can help when defining the measure. This will become increasingly important when your measures become more complex.

## DAX Uses Tabular Model Data Types

DAX assumes that all values in columns (and the inputs and outputs of all DAX formulas) are one of the following seven data types:

|  |  |
| --- | --- |
| **Data Type** | **Description** |
| Whole Number | Integer |
| Decimal Number | Double precision real number |
| Currency | Four decimal places of precision (integer divided by 10,000) |
| TRUE/FALSE | Boolean |
| Text | String |
| Date | Datetime values beginning with Mar 1, 1900 |
| Binary | Binary data imported from the data source (typically for image data) |


This is slightly different from Excel, where everything is either a number (real) or a string. In Excel, data types are handled by formatting numeric values rather than by using different data types. Note that date values in DAX, like Excel, are restricted to dates after March 1, 1900.

DAX also has functions that return tables of data, but those tables may not be the final value in a measure or calculated column. Tables are used only as intermediate results, and are passed as arguments into additional functions, so that a DAX formula eventually returns a scalar value that has one of the six data types mentioned above.


## Intro to Context – Row Context and Filter Context

In DAX, one of the most important concepts to understand is the *context* in which each DAX expression is evaluated. Context will be examined in more detail later in this document (after some DAX functions are described, so that meaningful examples can be shown,) but for now, it is enough to be aware that each formula may be evaluated in the context of a specific row of table data (a “row context”) and/or in the context of a specific set of filters (a “filter context”). For example, the formula for a calculated column will be evaluated for each row of a table, using the “row context”. Similarly, a measure that is placed into a PivotTable will be evaluated for each cell in the values area, and each of those cells has its own “filter context” which is the combination of the cell’s row labels, column labels, report filters, and slicers.

**Row Context**

****

**Filter Context**

****

## Functionality That Does Not Exist In Excel Formulas

PowerPivot includes capabilities such as (relationships between tables, dynamic aggregation, context modification, etc. that do not exist within Excel, and therefore we need to have DAX functions that provide functionality that goes beyond the scope of Excel formulas. The details of DAX functions are described later, but here are some of the DAX functions categories which don’t exist in Excel.


Tables and relationships require these classes of functions:

* Functions that navigate relationships between tables (more powerful than VLOOKUP)
* Functions that take tables as arguments (aggregation over a table, filtering a table, etc.)
* Functions that produce a table result (this result must then be an input to another function)

Dynamic measure aggregation requires these classes of functions:

* Functions that discover the current context for a calculation (e.g. has a specific filter been set?)
* Functions that modify the context for a calculation (e.g. calculate formula for all products or years)
* Functions that know about Time manipulation (e.g. parallel period, previous period, YTD, etc.)

For example, consider this PivotTable showing sales by country for the Current Period, month-to-date (MTD), year-to-date (YTD), Last Year, PriorYearMTD, and PriorYearYTD. These results are calculated using DAX time intelligence functions as well as DAX aggregation functions.



## DAX Operators and Constants

DAX supports the usual arithmetic operators (+ - \* / ^) for addition, subtraction, multiplication, division, and exponentiation. DAX supports the comparison operators greater than (>), less than (<), greater than or equal to (>=), less than or equal to (<=), equals (=), and not equals (<>). DAX uses the ampersand (&) operator for concatenation. DAX also has logical operators that consist of a double vertical bar (||) for logical OR, and double ampersand (&&) for logical AND. DAX does not support the use of “OR” or “AND” as keywords – users should use “||” and “&&” for these operations. DAX also supports TRUE and FALSE as logical constants.

# Simple DAX Functions

This section focuses on some basic DAX functions that do not require a full understanding of filter context. In subsequent sections of this paper, you will find a more detailed explanation of filter context, followed by a section on the DAX functions that interact with the filter context in various ways.

## BLANK() and Blank Values

When a field in a traditional database does not contain a value, the empty field is often referred to as a NULL value. In Excel, an empty cell is referred to as a “blank” cell. While NULL and BLANK are two closely related concepts, it is useful to consider the difference between them.

In databases that support NULL, all calculations involving NULL will return NULL. For example, NULL+3 generates a NULL result. Trying to perform arithmetic on any NULL will always return a NULL. This is useful in databases where there is a desire to call out the special case of a missing value and to differentiate that missing value from a zero in the data.

In Excel, when you have a BLANK cell in a column of data, Excel allows you to perform arithmetic on the cell and simply treats the blank cell as a zero (or an empty string, depending on the operation being performed.) For example, BLANK +3 generates a result of 3. This makes sense where you are trying to aggregate values and wish to ignore any missing values in the list. This treatment is different than is used by most database products for missing values, which are referred to as NULL, and where NULL +3 generates NULL. Since DAX follows the Excel logic, we use the term BLANK for missing values rather than NULL.

Note that there is one place where DAX differs from Excel, and this difference is quite intentional. When we have a formula which is adding up a column of numbers, and the entire column contains nothing but blanks, instead of generating a result of zero (which is what Excel does) DAX and PowerPivot will generate a result of BLANK. As long as there are any values in the column being aggregated, we will get a numeric result, but when all the values are BLANK, the result will also be BLANK.

We needed to have this difference in order to properly work in PivotTables. Imagine a database with a couple of thousand cities, and a set of sales that have been filtered to include only eight (8) of those cities. If we build a PivotTable and place [City] on rows, and [Sales] in values, we want to see a PivotTable with only eight rows. If the sum of blanks was zero (as it is in Excel) then we would get a PivotTable with two thousand rows and mostly zeroes everywhere. Allowing “empty” data sets to aggregate to BLANK is incredibly useful for PivotTables, since PivotTables automatically (by default) filter away any rows with blank results.

DAX has a function BLANK() that returns an empty (blank) value. This is useful when you want to test to see if the result of an expression is blank, because you can compare the expression to BLANK() . As you will see in the next section DAX also supports the Excel ISBLANK() function for the same purpose.

## Functions from Excel

DAX supports approximately eighty (80) functions from Excel. There are some specific differences from how these functions work in Excel, but generally these functions are so similar that the learning curve is likely to be very small. The description provided for each of these functions is intentionally brief because these functions are essentially the same as have been in Excel for many years. This document’s focus is primarily about DAX functions that are not available in Excel.

In places where the Excel function took a range (or a set of ranges,) the DAX function takes a column reference. For example, in DAX the function SUM doesn’t take a list of ranges. It takes a column reference and ads the values in that column.

In places where a function used to return the serial number representing a date, DAX will return the date itself using the date data type.

Logical functions AND and OR only allow for two arguments in DAX. CONCATENATE has the same limitation. To get around this limitation, we recommend using the operators instead of these functions as shown here:

|  |  |
| --- | --- |
| AND | && |
| OR | || |
| CONCATENATE | & |

Here are the Excel functions supported in DAX by Category:

|  |
| --- |
| **Date and Time** |
| DATE |
| DATEVALUE |
| DAY |
| EDATE |
| EOMONTH |
| HOUR |
| MINUTE |
| MONTH |
| NOW |
| SECOND |
| TIME |
| TIMEVALUE |
| TODAY |
| WEEKDAY |
| WEEKNUM |
| YEAR |
| YEARFRAC |
|  |
| **Information** |
| ISBLANK |
| ISERROR |
| ISLOGICAL |
| ISNONTEXT |
| ISNUMBER |
| ISTEXT |
|  |
| **Logical** |
| AND |
| IF |
| IFERROR |
| NOT |
| OR |
| FALSE |
| TRUE |
|  |
| **Math and Trig** |
| ABS |
| CEILING, ISO.CEILING |
| EXP |
| FACT |
| FLOOR |
| INT |
| LN |
| LOG |
| LOG10 |
| MOD |
| MROUND |
| PI |
| POWER |
| QUOTIENT |
| RAND |
| RANDBETWEEN |
| ROUND |
| ROUNDDOWN |
| ROUNDUP |
| SIGN |
| SQRT |
| SUM |
| TRUNC |
|  |
|  |
| **Statistical** |
| AVERAGE |
| AVERAGEA |
| COUNT |
| COUNTA |
| COUNTBLANK |
| MAX |
| MAXA |
| MIN |
| MINA  RANK.EQ  STDEV.P  STDEV.S  VAR.P  VAR.S |
| **Text** |
| CONCATENATE |
| EXACT |
| FIND |
| FIXED |
| LEFT |
| LEN |
| LOWER |
| MID |
| REPLACE |
| REPT |
| RIGHT |
| SEARCH |
| SUBSTITUTE |
| TRIM |
| UPPER |
| VALUE |

## FORMAT(Value, Format\_text)

Instead of Excel’s TEXT function, DAX has a FORMAT function for converting various numeric and date values to strings. This function works just like the FORMAT function in Visual Basic.

Start with a field named [TestDate] that is defined as: =DATE (2001, 1, 27) + TIME (17, 4, 23). In other words, we start with a date field that contains this date and time: Jan 27, 2001 5:04:23 PM.

The following examples illustrate how FORMAT can produce different strings from this value:

|  |  |
| --- | --- |
| **DAX Formula** | **Result** |
| =FORMAT([TestDate],"mmmm dd yyyy hh:mm:ss") | January 27 2001 17:04:23 |
| =FORMAT([TestDate],"mmm dd yyyy ddd hh:mm") | Jan 27 2001 Sat 17:04 |
| =FORMAT([TestDate],"dddd mmm-dd") | Saturday Jan-27 |

## Functions to Aggregate Expressions – the “X” Functions

DAX implements aggregation functions from Excel including SUM, AVERAGE, MIN, MAX, COUNT, STDEV.P, STEDEV.S, VAR.P, VAR.S, but instead of taking multiple arguments (a list of ranges,) they may take only a reference to a column. This can be somewhat limiting, so DAX also adds some new aggregation functions which aggregate any expression over the rows of a table. Here are the functions:

* SUMX (Table, Expression)
* AVERAGEX (Table, Expression)
* COUNTAX (Table, Expression)
* MINX (Table, Expression)
* MAXX (Table, Expression)
* STDEVX.P (Table, Expression)
* STDEVX.S (Table, Expression)
* VARX.P (Table, Expression)
* VARX.S (Table, Expression)

In each case, the first argument is a table over which you want to aggregate an expression, and the second argument is the expression to be aggregated.

Consider this example:

= SUMX(FactSales, [UnitPrice] \* [SalesQuantity])

This formula says we should start with the FactSales table, and for each row of that table we should evaluate the expression [UnitPrice] \* [SalesQuantity]. Then the results should be added up because we are using the SUMX function. If we had used AVERAGEX, we would be taking the average of all the results.

Consider the following three formulas are precisely identical to each other:

* =SUM(FactSales [SalesQuantity])
* =SUMX(FactSales, [SalesQuantity])
* =SUMX(FactSales, FactSales[SalesQuantity])

The first formula takes the sum of a column, the second formula takes the value from a column for each row of the table and adds them up, and the third formula simply provides a fully qualified name for the column.

These aggregation functions are particularly powerful in measures because the context in which they are evaluated will change (filter) the table over which the aggregation is being performed. For example, if we have a PivotTable with years in the column labels, and stores in the row labels, and then we place this formula:

**=SUMX(FactSales, [UnitPrice] \* [SalesQuantity])** into a measure, for each cell of the PivotTable, we’ll get the subtotal for the sales belonging to a particular year and store.

When we use functions like this in a measure we are effectively aggregating a table of data across many slices of the data. This is precisely the sort of data analysis for which PowerPivot and PivotTables are designed. A formula like this in a calculated column is far less interesting because the data set isn’t being sliced (unless you also use RELATEDTABLE, which is covered next.☺).

## COUNTROWS(Table)

COUNTROWS is similar to the other COUNT functions (COUNT, COUNTA, COUNTX, COUNTAX, COUNTBLANK) but it takes a table as its argument, and returns the count of rows in that table. For example, the formula =COUNTROWS(FactSales) will return the number of sales transactions in the FactSales table.

## RELATED(Column) and RELATEDTABLE(Table)


DAX introduces the functions RELATED and RELATEDTABLE for following relationships and retrieving related data from another table. This is more powerful than VLOOKUP in Excel in a couple of ways. First, VLOOKUP only returns the first match – there is no promise of referential integrity and no assurance there was not another row that would also have matched the lookup. Second, instead of requiring the lookup table to be organized in a particular way, with certain columns on the left-hand side, DAX functions rely on relationships between the two tables, and those relationships may involve any of the columns in a table.

RELATED(Column) follows existing many-to-one relationship(s) from the many side to the one side and returns the single matching value from the other table. Consider these examples:

In the FactSales table, we can add two calculated columns using these formulas:

1. =RELATED(DimStore[StoreName])
2. =RELATED(DimGeography[ContinentName])

These formulas will add two columns to the FactSales table, the first containing the name of each store and the second containing the continent name. The first of these examples follows a single relationship from FactSales to DimStore, while the second formula must navigate two relationships: from FactSales to DimStore and then from DimStore to DimGeography. Authoring this formula requires only that you know the name of the column from which you want to get a value.




RELATEDTABLE(Table) follows a relationship in either direction (many-to-one or one-to-many) and returns a table containing all the rows that are related to the current row from the specified table. This is very useful when you want to find all the transactions associated with a particular row of a related table.


Note: this function returns a table and not a scalar value. This means that this function cannot be used by itself to define a calculated column or a measure. Instead this function can only be used to provide an intermediate result that is in turn an argument to another function, such an aggregation function.


Consider this example: **=**SUMX(RELATEDTABLE(FactSales), FactSales[SalesAmount])

This formula says that we want to first construct a table that contains the rows from FactSales that are related to the current row. RELATEDTABLE(FactSales) assumes we have a current row and there is a relationship between the current table and the FactSales table. Once we have the table containing the related rows from the sales transactions, we will then take the SalesAmount from each row, and then add those sales amounts.

Let’s go ahead and place this formula into a calculated column in the DimProduct table. Then let’s place the exact same formula with no changes whatsoever into a calculated column in the Dim Store table. Finally we will place the same formula into the DimDate table. While we get completely different numbers in each of those three tables, we will see that we’re getting essentially the same thing: A total of the sales transactions broken down by each product, or by each store, or for each date.







The construct of aggregating across a related table of transactions is very common and provides a powerful way to break down transactions across the rows of a related table.

## USERELATIONSHIP(Column1, Column2)

USERELATIONSHIP specifies the relationship to be used in a specific calculation. The function uses existing relationships in the model, identifying relationships by their ending point columns.

Multiple relationships can exist between two tables in the data model, however only one active path can exist, directly or indirectly. This function allows you to specify the use of a non-active relationship. Active relationships are used by default in DAX expressions. The USERELATIONSHIP function can only be used in functions that take a filter as an argument, like CALCULATE which will be described later in this paper.

For example: =CALCULATE([Sales], USERELATIONSHIP(FactSales[ShipDateKey], ‘Date’[DateKey]))

***Note:*** *There is no ShipDateKey in the Contoso sample database.*

## FILTER(Table, Condition) and DISTINCT (Column)

FILTER and DISTINCT are two more DAX functions that return a table of results. Because each of these functions returns a table, they cannot be used as the outermost part of a formula placed in a calculated column or measure. Instead these functions will be used as arguments to other functions, typically aggregation functions.

FILTER (Table, Condition) returns a subset of the specified table where the condition is TRUE. It will always return all of the columns of the specified table, and some subset of the rows in that table. For example, the expression FILTER (FactSales, RELATED(DimGeography[CityName])="Baltimore") will return a table containing all the rows from FactSales that took place in the city of Baltimore. To get the sales total for the city of Baltimore, we would simply use this as the table argument to SUMX as follows:

=SUMX(FILTER(FactSales, RELATED(DimGeography[CityName])="Baltimore"), [SalesAmount])


DISTINCT(Column) returns a table containing the unique values within the specified column. In other words, a table of the values, with any duplicate values removed from the list. For example, the expression DISTINCT(FactSales[StoreKey]) will return a table containing the different Store IDs for which there were sales transactions.

# Row Context and Filter Context

Now that many of the basic DAX functions have been described, let’s look at some examples of what we mean by “Row Context” and “Filter Context” because they represent concepts that you need to understand in order to work with some of the more advanced DAX functions such as CALCULATE, described later in this document.

## Row Context


Row context is most easily thought of as the “current row”. This is most obvious in cases where a formula is being entered in a calculated column. For example, within the FactSales table, we can author a formula for a calculated column that looks like this: =[SalesQuantity] \* [UnitCost]



In this scenario, we are taking the values of the [SalesQuantity] and the [UnitCost] columns from the current row and multiplying the two numbers together. This seems both obvious and intuitive because the same approach works in Excel. But it is important to observe DAX takes the name of a column ([UnitCost]) and interprets it as a single value ($12.83) when there is a row context. When there is no row context, DAX cannot interpret the name of a column as a value. If we try to enter precisely the same formula in a measure, we will get an error message: “The value for 'SalesQuantity' cannot be determined. Either 'SalesQuantity' doesn't exist, or there is no current row for a column named 'SalesQuantity'.”In this case, the problem is there is no current row (or no row context), so there is no way to know what number to use for [SalesQuantity].

Let’s consider a different sort of row context that is based on scanning a table, rather than filling in values in a calculated column. Whenever a formula has a function that scans a table, that function will inherently apply a row context for each row of the table over which it is scanning. One example of this is the SUMX function. You may recall that SUMX takes two arguments – a table over which to aggregate, and an expression to be evaluated for each row in that table. This means that the expression will be evaluated using a row context for each row of the specified table. For example, we can define a measure as follows: =SUMX(FactSales, [SalesQuantity] \* [UnitCost]) and the measure will evaluate the total cost for each transaction (in the context of that row) and then add up the results.


Another way to think about row context is to think of it as a set of filters on a table that result in a single row remaining. For example, consider this table:



The first row of this table is the row where [ChannelKey]=1, [ChannelLabel]=”01”, [ChannelName ]=”Store”, and [ChannelDescription]=”Store”. Similarly, the fourth row of this table is the row where [ChannelKey]=4, [ChannelLabel]=”04”, [ChannelName ]=”Reseller”, and [ChannelDescription]=” Reseller”. Thinking about applying the filters of each column in a table to identify a single row is a great way to think of row context. Note that in this example, it’s enough to filter any one of the columns, but that will not always be the case.

## Filter Context

Filter context is more complex than row context and can most easily be described as the set of filters associated with one of the cells in the values area of a PivotTable. Consider the following PivotTable:



This PivotTable has only one measure, with a single DAX formula defined as **=**SUM(FactSales[SalesAmount])**.** That single formula is being evaluated 72 distinct times, with 72 different results, and each of those 72 results has a distinct ***Filter Context***. The context for each cell in the values area includes the items on the row labels, the column labels, the report filter, (and slicers if they were being used.) The cell that is highlighted above has the following ***Filter Context***.

* [RegionCountryName] = “Germany”
* [CalendarYear] = 2008
* [ChannelName] = ”Store”
* [ContinentName] = ”Europe”


This can be thought of as applying four filters to the FactSales table prior to evaluating the formula, which is simply the sum of the [SalesAmount] values for the rows that are left after applying those four filters. This is where the name “Filter Context” comes from.

## Relationships and Filter Context

When there is a relationship between two tables in PowerPivot, that relationship is always considered a “many-to-one” relationship that goes from the table containing “many” records for each instance of the key to the table containing “one” record for each instance of the key. For example, there is a many-to-one relationship from the table FactSales to the table DimProducts, with many rows for each product in FactSales, and only one row for each product in DimProducts.

It turns out that applying a filter to a table on the “one” side of the relationship will also cause the table on the “many” side of the relationship to be filtered. For example, if we filter DimProducts so only one product remains, then FactSales will also be filtered so it only contains the sales transactions for that one product. Applying a filter to the table on the “many” side of a relationship (filter FactSales to include only certain products) will not have any impact on the table on the “one” side of the relationship.

This is how PivotTables are designed to work, and if you look at some examples, it makes perfect sense. Consider the PivotTable below where DimGeography has been filtered to include only two countries. It is quite natural that FactSales is constrained by the same filter, even though [RegionCountryName] isn’t a field in the FactSales table. It is a field in a table that is on the “one” side of a relationship to FactSales.



## Measures and Filter Context

The formula that defines a measure is always evaluated multiple times – once for each cell in the values area. And each of those evaluations has its own filter context. Even the grand total in the PivotTable above for all countries and for all years is evaluated in its own context, namely the context where [RegionCountryName] = ALL, [CalendarYear] = ALL, and [ChannelName] = ”Store”.

The presence of filter context for all measure evaluations (and the presence of row context for calculated columns), is one of the reasons why you often cannot use the same formula to define a measure as you would use to define a calculated column. Generally, because a measure must be evaluated many times, including for any totals rows or columns, measure formulas must do some sort of aggregation. Most measure formulas will either be the aggregation (Sum, Count, Average, Min, Max, or DistinctCount) of an expression, or a formula involving other measures, or some combination of the two.

# More DAX Functions

## CALCULATE(Expression, SetFilter1, SetFilter2,...)


The CALCULATE function is very powerful and very useful, but is conceptually a bit more difficult than any of the other DAX functions described up to this point. CALCULATE allows any DAX expression to be evaluated in a specified filter context. This is equivalent to defining a measure and also defining a set of filters that will be used to provide a context in which the measure is to be evaluated. CALCULATE does the following:

1. Using the SetFilter arguments, it modifies the filter context
2. If there is a row context, it moves that row context onto the filter context
3. It evaluates the Expression in the newly modified filter context

Here are some examples that illustrate how this works.


**Example1 – CALCULATE Without Any SetFilter Arguments**

Using the sample data from the Contoso database, let’s start by adding a calculated column to the FactInventory table with this formula: =COUNTROWS(FactSales)



We should not be surprised when we get the number of rows (approx 3.4 million) in the FactSales table, and we get the same result for every cell in the new calculated column.

Now let’s change the formula to this: =CALCULATE(COUNTROWS(FactSales)). Observe that we get two different values in the calculated column, either a blank or the value 1. Why did this happen?



First, CALCULATE caused the current row context to be placed onto the filter context. This means that the filter context got a set of filters that look like this:

* [InventoryKey] = <value in this row>
* [DateKey] = <value in this row>
* [StoreKey] = <value in this row>
* [ProductKey] = <value in this row>
* [CurrencyKey] = <value in this row>
* [OnHandQuantity] = <value in this row>
* [OnOrderQuantity] = <value in this row>
* Etc.... for every field in the FactInventory table (every field in the row context)

What makes this a bit more complicated is the row context is not merely the current row from that table, but actually the current row from that table as well as the current row from all tables on the one side of a many-to-one relationship from that table. Until now, it has been simpler to think of the row context as being from a single table, but it actually includes the current row from the entire set of related tables. This means the row context is the current row from FactInventory, as well as the current row from DimDate, the current row from DimProduct, and the current row from DimStore. This means the filter context also got a set of filters that look like this:

* [DateKey] = <value in the related row in DimDate>
* [FullDateLabel] = <value in the related row in DimDate>
* Etc.... for every field in the DimDate table
* [ProductKey] = <value in related row in DimProduct>
* [ProductLabel] = <value in related row in DimProduct>
* Etc.... for every field in the DimProduct table
* [StoreKey] = <value in related row in DimStore>
* [StoreType] = <value in related row in DimStore>
* Etc.... for every field in the DimStore table

Now, using that modified filter context, we want to count the rows in the FactSales table using the modified filter context. This is just like performing a calculation for a measure in a PivotTable where all of these filters have been placed on the PivotTable. Note that many of the fields above do not have any impact on the FactSales table, but some of them do. The filters from the DimDate, DimStore, and DimProduct tables are all fields for which there is a relationship to FactSales, so this filter context has effectively filtered the FactSales table down to the rows that have a specific date, store, and product. It turns out with this data set, the filtered FactSales table has either no rows, or a single row. Therefore the formula results in a value of BLANK or 1 depending on the values in the FactInventory row.

**Example2 – SetFilter Arguments**


The SetFilter argument is used to modify the context in which an expression is going to be evaluated.

Let’s say we want to do some analysis on sales data. Let’s define a simple measure on the FactSales table named [Sales] that is defined by this DAX formula: =SUM(FactSales[SalesAmount]). [Sales] is nothing more than the sum of the [SalesAmount] field for all the sales transactions contained in any particular slice of the data. But there’s a twist because the Contoso sales data includes sales made via four distinct channels: There are “Catalog” sales, “Online” sales, “Reseller” sales, and “Store” sales. Each of these is a separate row in the DimChannel table, and every FactSales row is identified as belonging to one of these channels by the [ChannelKey] field in that table. (There is of course a many-to-one relationship from FactSales to DimChannel.)

Suppose the sales analysis we want to perform is to be based on Store Sales worldwide. We expect various people in our department to slice the sales data a variety of ways – by country, by time, by store, by product, and by any of the fields available in the database. But we want to make sure that no matter what they choose, they are only looking at sales in the “Store” channel. If we don’t do anything special, we run the risk the analysis will inadvertently combine store sales with other kinds of sales, because they might forget to place a Channel filter on their PivotTable.

Note this would be an easy mistake to make because the sales data for Contoso includes Store sales in 34 countries. In 30 of those countries, Store sales is all there is. In this data set, Catalog sales are limited to the United States, Online sales are limited to three countries (US, Germany, China), and Reseller sales are also limited to three countries (US, France, China). Someone analyzing sales in Canada would not see any difference between Store Sales and Sales for all channels, but someone analyzing data for the US or China would see a dramatic difference.

To force the values to be from the “Store” channel, we will define a new measure named [StoreSales] which is defined as: =CALCULATE([Sales], DimChannel[ChannelName] = ”Store”). The SetFilter argument within CALCULATE ensures that it will override any filter (if any) on the Channel Name column with a new filter that says we only want sales in the Store channel. By using this measure, we are guaranteed to be looking at Store sales, and we don’t have to rely on PivotTable authors to place the Channel somewhere on their PivotTable.



**Syntax Shortcut for CALCULATE(Expression [,SetFilter1] [,SetFilter2]...)**

When you have a CALCULATE function where the expression to be evaluated is simply a measure, then there is a convenient shortcut available. Let’s consider the example above.

= CALCULATE([Sales], DimChannel[ChannelName] = ”Store”)

In order to make certain common cases easier to author and easier to read, we offer the following shortcut:

When the expression to be evaluated is a measure, a shortcut for CALCULATE(<measure>, <optional SetFilters>) is to use the name of the measure as if it were a function name and write this instead:

=<MeasureName>(<optional SetFilters>)

When we apply this to our example, we find that StoreSales can be defined as:

=[Sales](DimChannel[ChannelName] = ”Store”)

This is easier to read and author and we will use this notation in several places going forward.

**More Information About SetFilter Arguments**

A SetFilter argument in CALCULATE may be either of the following:

1. A boolean expression that refers to a single column such as ***DimChannel [ChannelName] =”Store”*** or ***(DimGeography[CityName]=”Seattle” || DimGeography[CityName]=”Portland”)***. Note that the boolean expression may not refer to measures and may not invoke the CALCULATE function nor any table scanning functions including aggregation functions or table valued functions.
2. A table expression such as ***Filter(Table1, Condition)***

Let’s consider how a table SetFilter should be interpreted. Consider a table which contains three columns named “City”, “Product”, and “Month”. The rows in the table specify the valid combinations of values for those columns. Any combination of values not present in the table is filtered away. In other words, we can pass a table like this as a SetFilter argument to the CALCULATE function, and it will filter away any combinations of city, product, and month that aren’t in this table.

|  |  |  |
| --- | --- | --- |
| **[City]** | **[Product]** | **[Month]** |
| Seattle | Bike | Jan 2008 |
| Seattle | Car | Feb 2008 |
| Boston | Bike | Mar 2008 |

The most common scenario for using a table as a SetFilter argument to the CALCULATE function is the ALL function which will be illustrated later in this paper.

## VALUES(Column)


The VALUES function will return all the valid values for that column in the current filter context. The result comes back as a table of values, even though the table may have only one value (or even no values). This function is an easy way to ask about the current filter context. This function will often be used within an IF function. Imagine a scenario where you want to do one calculation when the country is the United States, and a different calculation when the country is not the United States. This can be accomplished by testing to see if VALUES(DimGeography[RegionCountryName]) = “United States”. Of course there might be a PivotTable where the country isn’t specified, or a situation where multiple countries have been selected and we can only compare a table to a single value when the table has only one value.

This forces us to write something like this to determine what the current country is:

=IF(HASONEVALUE(DimGeography[RegionCountryName]), VALUES(DimGeography[RegionCountryName]), "No single country selected")

The HASONEVALUE function returns TRUE when the context for the column has been filtered down to one distinct value only. This function is very convenient for testing whether the VALUES function will return a single value in which case it can be referenced as a scalar value.

This formula says that if there is only one country selected in the current context, return the name of that country, else return the expression “No single country selected”. The result of placing this measure in a PivotTable where the country is on Row Labels looks like this:



## CALCULATETABLE(TableExpression, SetFilter1, SetFilter2,...)

CALCULATETABLE is just like CALCULATE, except the expression and the result are both tables. This would be used when you want to change the filter context and then construct a table in that new context.

## ALL(Table) and ALL(Column1 [,Column2]...)


The ALL function is a table-valued function which causes the filter context for the specified columns to be ignored. This function is particularly useful when used as a table-valued SetFilter argument within the CALCULATE function. Consider some examples:

ALL(DimProduct) returns a table containing all the rows within DimProduct, ignoring any filters that may be present in the filter context. Duplicate rows will be removed. Because the argument to ALL is a table, the filter context is effectively removed from all columns in that table.

ALL(Column1) returns a table containing all the values from Column1 (without any duplicates) after removing/ignoring any filters from the filter context that may have been present on that column.

When multiple column arguments are supplied to the ALL function, it is required that all of those columns belong to the same table. For example, ALL (Column1, Column2) returns a table with two columns from a source table, consisting of all the combinations of Column1 and Column2 that were present in the original data removing/ignoring any filters from the filter context that may have been present on those columns.


Consider the measure FactSales[Sales] that has been defined as =SUM(FactSales[SalesAmount]). By itself, the measure [Sales] is the sum of the SalesAmount column for whatever the current context may be. Looking at the PivotTable below, you see that this is a different number in each cell of the PivotTable because each cell has a different context (a different product category and year).



Now, let’s add another measure to the PivotTable. Let’s add RatioAllProd which is the sales for a given context divided by sales for all products (in the same year). There are two ways to write this, one using CALCULATE, and another using our shortcut syntax:

* =[Sales]/CALCULATE([Sales], ALL(DimProduct))
* =[Sales]/[Sales](ALL(DimProduct))

Note that by removing/ignoring the filter context on DimProducts, we are also removing/ignoring the filter context on all tables on the “one” side of a relationship with DimProducts (SubCategory and Category tables).





There is one important thing to note about this formula: =[Sales]/[Sales](ALL(DimProduct)). We have changed the filter context for the denominator of this ratio without changing it for the numerator. This is a very common BI scenario. We need to calculate something compared to that same thing but for a different set of products, or for a different year, or for a different region, etc. Changing some part of the filter context for some portion of the formula is very powerful.

Let’s look at one more example, this time comparing sales for each of our four channels to store sales and also to all sales. We’ll define two new measures:

* RatioStore: =[Sales]/[StoreSales]
* RatioAllChan: =[Sales]/[Sales](ALL(DimChannel))

Then I’ll place these measures in a couple of different PivotTables that have different row and column headers to illustrate how a measure can make sense no matter what PivotTable it is placed on. This makes it important to define measures carefully, because once defined, users are free to place them on PivotTables that might be organized quite differently from what was originally anticipated.





## ALLEXCEPT(Table [,Column1] [,Column2]...)

ALLEXCEPT is a shorthand notation for a series of ALL functions. Imagine a table that has 43 columns, and let’s say you want to remove/ignore the filter context from 40 of those columns, and retain the filter context on three of them. You can accomplish this in two ways:

* ALL(Column1, Column2,... <repeated for 40 columns>) removes the context for the forty columns specified here.
* ALLEXCEPT(Table, Column1, Column2, Column3) removes the context for all the columns in the specified table except the three columns that are specified here.


This is nothing more than a convenient shortcut for specific situations where you want to remove/ignore the context on many (but not all) columns in a table.

## RANKX(Table, Expression [,Value] [,Order] [,Ties]…)

The RANKX function returns a ranking of a number in a list of numbers for each row in the Table argument. The function can optionally take a Value argument that represents a scalar value whose rank is to be found. The optional Order argument specifies how to rank Value, descending (0) or ascending (1). The optional Ties argument defines how to determine ranking when there are ties. Skip (default) will use the next rank value after a tie, and Dense will use the next rank value (i.e. there will be no gaps in the rank numbers).

The following example illustrates using the RANKX function to rank the sales by product color. The two measure expressions are:

* Sales:=SUM(FactSales[SalesAmount])
* ColorRank:=RANKX(ALL(DimProduct[ColorName]), [Sales])



In this example the RANKX function compares the value of the Sales measures for each row in the PivotTable against the values of the Sales measure for all rows of DimProduct[ProductColor] thus producing the rank for the current row.


When the PivotTable rows are sorted by Sales, the rank calculation is clearer.




## RANK.EQ(Value, ColumnName [,Order])

Returns a ranking of a number in a list of numbers with its size relative to other values in the list. The last argument is an optional value (0 or 1) that specifies how to rank number, low to high (ascending) or high to low (descending). By default the order is descending (0).

The following example is a calculated column representing the rank of the each product (row) in descending order.



This example is the same calculation, except the Order argument is set to 1 (ascending).



## TOPN(N\_Value, Table [,OrderBy\_Expression1] [,Order1] [,OrderBy\_Expression2] [,Order2]…)


The TOPN function returns the top N rows of a specific table, optionally ordered by expressions, ascending or descending. The Expression arguments can be based on columns or measures. The argument following the OrderBy\_Expression is a value (0 or 1) that specifies how to order the table. 0 sorts in descending order of values of the OrderBy\_Expression, and 1 sorts them in ascending order.

As the function returns a table, it will need to be aggregated when used in a calculated column or measure. The following examples will sum the table returned by the TOPN function to calculate the top three and bottom three products by sales.

The three measure expressions are:

* Sales =SUM(FactSales[SalesAmount])
* Top3ProductSales =SUMX(TOPN(3, DimProduct, [Sales]), [Sales])
* Bottom3ProductSales =SUMX(TOPN(3, DimProduct, [Sales], 1), [Sales])

In the following example, the PivotTable presents Sales by StockTypeName on the rows, and the three measures Sales, Top3ProductSales and Bottom3ProductSales as Values.



## LOOKUPVALUE(Result\_ColumnName, Search\_ColumnName1, Search\_Value1 [,Search\_ColumnName2] [,Search\_\_Value2]…)

The LOOKUPVALUE function returns the value in Result\_Column for the row that meets all criteria specified in the search arguments. If no match satisfies the search values a BLANK is returned. If multiple rows match the search values, and all Result\_Column values are identical, it will be returned, otherwise an error is returned.


This function is useful in a number of different scenarios. It is commonly used in conjunction with the parent-child functions to lookup the member name against a key. Refer to the example of the PATHITEM function in the Parent-Child section in this paper.

## ALLSELECTED()


The ALLSELECTED function gets the context that represents all rows and columns in the query, while keeping explicit filters and contexts other than row and column filters. This function can be used to obtain visual totals in queries. It takes either no arguments, or either a table or column reference.

In the following example, the PivotTable presents Sales by StockTypeName on the rows, and includes the ability to filter the result by using the ClassName slicer. When all ClassName values are selected (i.e. there is no filter) this report works fine. The three measure expressions are:

* Sales =SUM(FactSales[SalesAmount])
* Sales\_ALL =CALCULATE([Sales], ALL(FactSales))
* SalesRatio\_ALL =[Sales]/[Sales\_ALL]




When a ClassName value is selected, notice the Sales\_ALL measure is evaluated using all rows in the FactSales table. The Grand Total values for Sales and Sales\_ALL differ, with the latter calculation based on all FactSales rows. The ClassName filter does not apply to the Sales\_ALL calculation.



Now two additional measures are added and the Sales\_ALLSELECTED measure uses the ALLSELECTED function.

* Sales\_ALLSELECTED =CALCULATE([Sales], ALLSELECTED())
* SalesRatio\_ALLSELECTED =[Sales]/[Sales\_ALLSELECTED]



Noitce the Sales\_ALLSELECTED measure takes into consideration the ClassName filter, and that the Grand Total values for Sales and Sales\_ALLSELECTED are the same. Also notice the SalesRatio\_ALLSELECTED values sum to 100%. These additional calculations using the ALLSELECTED function produce the effect of visual totals.

When defining measures that should display the visual total (and not explicitly override a specific table or column) you should use the ALLSELECTED function rather than the ALL function. When using ALLSELECTED function, the function will always return the visual total regardless of what is on rows and column.


# Time Intelligence Functions

One of the most common calculations performed in data analysis is to compare some number to a comparable number for a different time period. Calculations that make comparisons to last month or to the same period from a year ago are very important for any business intelligence tool. Toward that end, DAX includes 35 functions expressly for the purpose of working with time based data.

## Concepts and Best Practices

Whenever you are defining measures and working with time periods, there are many opportunities to make bad assumptions about what the PivotTable in which the measure will be used might look like. To avoid a lot of those problems, DAX makes certain assumptions and we recommend certain best practices for anyone planning to use the time intelligence functions described in this section.

We recommend you create a table in your PowerPivot data that contains one row for every date that might exist in your data. Many people think of this as a date table or a time table or a time dimension. The notion is that this table has one row for each date, and there should be a many to one relationship from any date columns in the database to this date table. Building such a table in Excel is fairly trivial to do, and it might look like the table below, or like the DimDate table in Contoso.



DAX uses this table to construct a set of dates for each calculation. The only column that matters is the date column itself. There are no requirements whatsoever about any of the other columns, and they aren’t needed by DAX, although you may find them useful when you build PivotTables. You need to provide a reference to the Date column as an argument to every one of the 35 time intelligence functions in DAX.

The model developer can mark the Date table and define which Date type column in the table expresses the date. This allows the model tables to use a non-Date type key, which is common in data warehouse fact tables that use integer keys (typically the date in ISO format, e.g. 20110913). The model developer must ensure that the Date table contains one row per date and that there are no date gaps in the table data. Also, the model developer must ensure the table is marked as a date table.

This simple configuration will ensure that the Time Intelligence functions will function correctly, and also Excel will be aware that columns in the Data table can use time-related filters.

In DAX, we always calculate a set of dates as a table and then use that as if it were a SetFilter argument to the CALCULATE function. Consider that a user might have multi-selected some dates within a PivotTable, so that the context for a calculation might be any of the following:

* A single date
* A set of contiguous dates
* A set of non-contiguous dates
* Dates that happen to correspond to a calendar month or quarter or year (very common)

Then consider that we might need to shift those dates to find the following:

* The dates that make up the previous day, month, quarter, or year
* The same dates shifted to a previous month, quarter, or year
* The same dates shifted some interval of time (14 days, 30 days, etc.)
* Dates calculated by shifting an arbitrary interval forward or backward in time

In DAX, we accomplish all of these by working with sets of dates for everything. We don’t try to know anything about month or quarter or year columns, but we do know the dates for any given month.

In the initial release of PowerPivot, we did not try to handle the many custom calendars we knew exist for financial analysis, but we do allow folks to build those custom calendars by authoring custom formulas to handle such things as 13 four week months in a year, or 4-4-5 quarters, etc.

The built-in functions handle calendar or fiscal years where fiscal year is defined as having a yearend date other than Dec 31. They also know about months, so when we shift the period April 1-30 back one month, we know we want March 1-31, and not merely March 1-30. This requires snapping to the end of a month in a variety of situations. In general DAX handles calendar quarters as 3 months, and years as 12 months, so all of the internal calculations are really based on days or months.

In the next section(s) of this paper, we look at the specific time intelligence functions in DAX and how they work.

## Functions that Return a Single Date

The functions in this category return a single date. The result of these functions might then be used as arguments to other functions.

The first two functions simply return the first (or last) date in the Date\_Column in the current context. This can be useful when you want to find the first (or last) date on which you sold each product, or the first (or last) date on which you had a transaction of a particular type. These functions take only one argument, the name of the date column in your date (or time) table.

* FIRSTDATE(Date\_Column)
* LASTDATE(Date\_Column)

The next two functions aren’t strictly time intelligence functions, because they can be used for other purposes, but they will most often be used for time calculations. They are used to find the first (or last) date (or any other column value as well) where an expression has a non-blank value. This is most often used in situations like inventory, where you want to get the last inventory amount, and you don’t happen to know when the last inventory was taken.

* FIRSTNONBLANK(Date\_Column, Expression)
* LASTNONBLANK(Date\_Column, Expression)

Here is an example from Contoso that shows how to calculate inventory using LASTNONBLANK. Note this is a fairly complex calculation, so we’re going to take the time to describe it.

Let’s look first at the FactInventory table in Contoso. This table contains a set of transactions where inventory was counted for various products in various stores. Each transaction identifies:

* a specific date
* a specific store
* a specific product
* an on-hand quantity

Note inventory quantities do not add. If we count 3 widgets one day, and 2 widgets a week later, the net result is we have 2 widgets (until another transaction occurs to change the quantity on hand.) At any moment in time, the on-hand-qty is the last count that was taken of that product in that store.

While inventories do not add within a store and within a product, they do add across stores and across products. If we have 3 apples and 2 oranges in one store, and 5 apples and 4 oranges in another, then we can say we have a total of 8 apples and 6 oranges, and we can even say we have a total of 14 products.

So how do we author this formula using DAX? (Warning – we are going to intentionally make a mistake in this process, and will point it out later, along with the necessary adjustment. Please bear with us.)

First, we need to know the quantity on hand for each product in each store. This is where LASTNONBLANK comes in. We also need to add these numbers up across a list of stores and a list of products, which are available to us as the DimStore and DimProduct tables. Consider this pair of formulas:

[BaseQty] = SUM(FactInventory[OnHandQuantity])

[QtyOnHand] = SUMX(VALUES(DimStore[StoreKey]),

SUMX(VALUES(DimProduct[ProductKey]),

CALCULATE([BaseQty],

LASTNONBLANK(DimDate[Datekey],[BaseQty]))))

These formulas say the following:

Define [BaseQty] as the sum of the OnHandQuantity amounts in FactInventory

Define [QtyOnHand] as a nested aggregation (nested sum) where

For each Store,


For each Product,

For the last date where there is a non-blank [BaseQty],


Calculate the [BaseQty],

Then add up those results across products and stores.

A PivotTable with this measure appears (at first glance) to give the right results. Let’s look at this using just a couple of products in a couple of Canadian stores as examples. The last date is used for each product, and the quantities add up across multiple products and stores.



So what’s the problem? We haven’t anticipated what might happen when someone slices this PivotTable using Time. For example, let’s add Years to column labels and take another look at the results:



For Product 7 (Contoso 2G MP3 Player E200 Blue) the last inventory transaction occurs in 2008. When we are doing inventory calculations for 2009, since there are no inventory transactions, we report there is no inventory. But that’s not true, because we still have the inventory left over from 2008.

This means we need to change our calculation, so that we change the context for time to include all the transactions from the beginning of time up until the current context. In order to do this, we need another time intelligence function we haven’t gotten to yet. We’ll come back to this example once we’ve described the function we’ll need.

Six more functions that return a single date are the functions that return the first or last date of a month, quarter, or year within the current context of the calculation.

* STARTOFMONTH(Date\_Column)
* STARTOFQUARTER(Date\_Column)
* STARTOFYEAR(Date\_Column [,YE\_Date])
* ENDOFMONTH(Date\_Column)
* ENDOFQUARTER(Date\_Column)
* ENDOFYEAR(Date\_Column [,YE\_Date])

## Functions that Return a Table of Dates

There are sixteen time intelligence functions that return a table of dates. Most often, these functions will be used as a SetFilter argument to CALCULATE. Just like all Time Intelligence functions in DAX, each function takes a column of dates as one of its arguments.

The first eight functions in this category are reasonably straightforward. Each of these functions starts with a date column in a current context. For example, if we are calculating a measure in a PivotTable, there might be a month or year on either the column labels or row labels. The net effect is the date column is filtered to include only the dates for the current context. Starting from that current context, these eight functions then calculate the previous (or next) day, month, quarter, or year and return those dates in the form of a single column table. Note the “previous” functions work backward from the first date in the current context, and the “next” functions move forward from the last date in the current context.

* PREVIOUSDAY(Date\_Column)
* PREVIOUSMONTH(Date\_Column)
* PREVIOUSQUARTER(Date\_Column)
* PREVIOUSYEAR(Date\_Column [,YE\_Date])
* NEXTDAY(Date\_Column)
* NEXTMONTH(Date\_Column)
* NEXTQUARTER(Date\_Column)
* NEXTYEAR(Date\_Column [,YE\_Date])

The next four functions in this category are similar, but instead of calculating a previous (or next) period, they calculate the set of dates in the period that is “month-to-date” (or quarter-to-date, or year-to-date, or in the same period of the previous year). These functions all perform their calculations using the last date in the current context. Note that SAMEPERIODLASTYEAR requires the current context contain a contiguous set of dates. If the current context is not a contiguous set of dates, then SAMEPERIODLASTYEAR will return an error.

* DATESMTD(Date\_Column)
* DATESQTD(Date\_Column)
* DATESYTD(Date\_Column [,YE\_Date])
* SAMEPERIODLASTYEAR(Date\_Column)

The last four functions in this category are a bit more complex, and also a bit more powerful. These functions are used to shift from the set of dates that are in the current context to a new set of dates.

* DATEADD(Date\_Column, Number\_of\_Intervals, Interval)
* DATESBETWEEN(Date\_Column, Start\_Date, End\_Date)
* DATESINPERIOD(Date\_Column, Start\_Date, Number\_of\_Intervals, Interval)
* PARALLELPERIOD(Date\_Column, Number\_of\_Intervals, Interval)

DATESBETWEEN calculates the set of dates between the specified start date and end date. The remaining three functions shift some number of time intervals from the current context. The interval can be day, month, quarter or year. These functions make it very easy to shift the time interval for a calculation by any of the following:

* Go back two years
* Go back one month
* Go forward three quarters
* Go back 14 days
* Go forward 28 days

In each case, we only need to specify which interval, and how many of those intervals we want to shift. A positive interval will move forward in time, while a negative interval will move back in time. The interval itself is specified by a keyword of DAY, MONTH, QUARTER, or YEAR. Note these keywords are not strings, so they should not be in quotation marks. It’s also useful to note that auto-complete doesn’t yet help to fill in these keywords, so you simply have to type them in.

Let’s look at some examples of how these functions might be used with the Contoso data set:

### Year Over Year Growth

The problem we want to solve is to calculate year-over-year growth for Store Sales. Although we’ve had formulas for StoreSales earlier in this paper (based on a [Sales] measure) let’s assume that formula is no longer handy and we want to start over with the Contoso database. A formula that might have seemed complicated before is now pretty straightforward:

[StoreSales] = CALCULATE(SUM(FactSales[SalesAmount]), DimChannel[ChannelName] = "Store")

In other words, Store Sales is defined as the sum of the SalesAmount column in the FactSales table, with the context modified to include only sales where the Channel Name in the DimChannel table is “Store”.

Now we want to calculate StoreSales for the previous year.

[StoreSalesPrevYr] = CALCULATE([StoreSales], DATEADD(DimDate[DateKey], -1, YEAR))

Since we’re calculating a single measure in a modified context, this can be written using a syntax shortcut.

[StoreSalesPrevYr] = [StoreSales](DATEADD(DimDate[DateKey], -1, YEAR))


Now we can calculate Year over Year Growth by simply subtracting last year’s sales from this year’s sales and showing that difference as a percentage of last year’s sales.

[YOYGrowth] = ([StoreSales] - [StoreSalesPrevYr]) / [StoreSalesPrevYr]

Finally we need to wrap this in an IF statement, so we don’t get division by zero in the first year.

[YOYGrowth] = IF([StoreSalesPrevYr], ([StoreSales] - [StoreSalesPrevYr]) / [StoreSalesPrevYr], BLANK())

Place [StoresSales] and [YOYGrowth] in a PivotTable with countries on rows, and years on columns:




### Calculating Many Time Periods Within a Single Measure Formula

Consider the following eight calculations. Each of these formulas calculates a sales amount (in the Contoso database) for a distinct time period.

|  |  |
| --- | --- |
| **Time Period** | **Formula** |
| Current Period | =[Sales] |
| MTD | =[Sales](DATESMTD(DimDate[Datekey])) |
| QTD | =[Sales](DATESQTD(DimDate[Datekey])) |
| YTD | =[Sales](DATESYTD(DimDate[Datekey])), |
| Current Period Last Year | =[Sales](DATEADD(DimDate[Datekey],-1,YEAR)) |
| PriorYearMTD | =[Sales](DATEADD(DATESMTD(DimDate[Datekey]),-1,YEAR)) |
| PriorYearQTD | =[Sales](DATEADD(DATESQTD(DimDate[Datekey]),-1,YEAR)) |
| PriorYearYTD | =[Sales](DATEADD(DATESYTD(DimDate[Datekey]),-1,YEAR)) |

Let’s create a new table named DimPeriod in PowerPivot that has a single column named Period, by pasting in a set of text strings like this from Excel:



Now let’s build a single measure formula that does the following:

1. Use an IF function, to see if the DimPeriod[Period] column has been placed into the Filter Context by placing this column onto the PivotTable’s column labels, or row labels, or perhaps on a slicer. The best way is to count the number of values that are applicable from this column. If this isn’t in the filter context, all 8 values will be applicable. But if this is on columns or rows, then only one of the values will be applicable for each cell in the values area (except for the Total row/column).
2. If only one of these values is applicable, then use a SWITCH statement nested in an IF statement to see which one it is, and apply the appropriate formula.
3. If this column is not on rows or columns (or selected to a single value in a slicer) then assume the user wants Current sales figure instead of one of the more elaborate calculations.

Such a formula would look like this:

=IF(HASONEVALUE(DimPeriod[Period]),

SWITCH(VALUES(DimPeriod[Period],

"Current", [Sales],

"MTD", [Sales](DATESMTD(DimDate[Datekey])),

"QTD", [Sales](DATESQTD(DimDate[Datekey])),

"YTD", [Sales](DATESYTD(DimDate[Datekey])),

"LastYear", [Sales](DATEADD(DimDate[Datekey],-1,YEAR)),


"PriorYearMTD", [Sales](DATEADD(DATESMTD(DimDate[Datekey]),-1,YEAR)),

"PriorYearQTD", [Sales](DATEADD(DATESQTD(DimDate[Datekey]),-1,YEAR)),

"PriorYearYTD", [Sales](DATEADD(DATESYTD(DimDate[Datekey]),-1,YEAR)),

BLANK()))

Now if we build a PivotTable with DimGeography[RegionCountryName] on row labels, DimPeriod[Period] on column labels, a single date from DimDate[FullDateLabel] in the Report Filter, and my new formula as the only measure, we will get a PivotTable that looks like this:



**Finishing Up Our Inventory Scenario**

We now have the functions we need to finish up the Inventory problem we were looking at.

The formula we had before was:

[QtyOnHand] = SUMX(VALUES(DimStore[StoreKey]),

SUMX(VALUES(DimProduct[ProductKey]),

CALCULATE([BaseQty],

LASTNONBLANK(DimDate[Datekey],[BaseQty]))))

And the problem was LASTNONBLANK was getting the last non-blank date from within the current context, when it should have been considering a larger time period. For example, when we are calculating inventory for 2009, we need to consider the last time inventory was taken from the beginning of time up through 2009. When in the context of the year 2009, the formula above only considers inventory transactions within 2009, and doesn’t consider transactions that may have occurred prior to 2009.

We can fix the formula by using DATESBETWEEN whose function signature looks like this:

DATESBETWEEN(Date\_Column, Start\_Date, End\_Date)

We’ll use a blank start date (to signify that we want to start at the absolute beginning), and we’ll use the last date from the current context as our end date. This means that we want this expression:

DATESBETWEEN(DimDate[DateKey], BLANK(), LASTDATE(DimDate[DateKey]))

And we’ll use this expression in place of the date column in LASTNONBLANK, since we want LASTNONBLANK to consider the expanded range of dates:

[QtyOnHand] = SUMX(VALUES(DimStore[StoreKey]),

SUMX(VALUES(DimProduct[ProductKey]),

CALCULATE([BaseQty],

LASTNONBLANK(

DATESBETWEEN(DimDate[DateKey], BLANK(), LASTDATE(DimDate[DateKey])),

[BaseQty]))))

Note that we could have used our syntax shortcut for CALCULATE(<measure>) here as well:

[QtyOnHand] = SUMX(VALUES(DimStore[StoreKey]),


SUMX(VALUES(DimProduct[ProductKey]),

[BaseQty](LASTNONBLANK(

DATESBETWEEN(DimDate[DateKey], BLANK(), LASTDATE(DimDate[DateKey])),

[BaseQty]))))

The good news is that our inventory now looks correct across dates, and items last counted in 2008 appear in the inventory for 2009 as well as for 2010 and 2011, where we know we have no inventory transactions.



## Functions that Evaluate Expressions Over a Time Period

There is one more set of Time Intelligence functions in DAX – these are the functions that evaluate an expression over a specified time period. These functions are all provided as a convenience. You can accomplish the same thing using CALCULATE and other Time Intelligence functions. For example,

=TOTALMTD(Expression, Date\_Column [, SetFilter])

This expression is precisely the same as this combination of functions:

=CALCULATE(Expression, DATESMTD (Date\_Column)[, SetFilter])

But it will be simpler and easier for users to use these DAX functions when they are a good fit for the problem that needs to be solved. The DAX functions that do this are:

* TOTALMTD(Expression, Date\_Column [, SetFilter])
* TOTALQTD(Expression, Date\_Column [, SetFilter])
* TOTALYTD(Expression, Date\_Column [, SetFilter] [,YE\_Date])


For the functions that calculate opening and closing balances, there are certain concepts that are useful. First, as you might think obvious, the opening balance for any period is the same as the closing balance for the previous period. The closing balance includes all data through the end of the period, while the opening balance does not include any data from within the current period.

These functions always return the value of an expression evaluated for a specific point in time. The point in time we care about is always the last possible date value in a calendar period. The opening balance is based on the last date of the previous period, while the closing balance is based on the last date in the current period. The current period is always determined by the last date in the current date context.

* OPENINGBALANCEMONTH(Expression, Date\_Column [,SetFilter])
* OPENINGBALANCEQUARTER(Expression, Date\_Column [,SetFilter])
* OPENINGBALANCEYEAR(Expression, Date\_Column [,SetFilter] [,YE\_Date])
* CLOSINGBALANCEMONTH(Expression, Date\_Column [,SetFilter])
* CLOSINGBALANCEQUARTER(Expression, Date\_Column [,SetFilter])
* CLOSINGBALANCEYEAR(Expression, Date\_Column [,SetFilter] [,YE\_Date])


# Parent-Child Functions

DAX includes a set of functions specifically to work with data stored in a table with a self-referencing relationship. Tables with this type of relationship are designed to store relationships between the records in the same table. The examples used to illustrate these functions in this paper are based on the DimEmployee table which includes a primary key column named EmployeeKey, and the ParentEmployeeKey column which is a foreign key constraint referencing the primary key.



Note tabular models cannot define self-referencing relationships; however, by using DAX the implied relationships can be materialized and used in calculations. Oftentimes this type of relationship is used to create a hierarchy referred to as a parent-child hierarchy, and common scenarios that can benefit from this type of hierarchy include general ledger and organizational structures.


A useful first step when working with the parent-child functions is to create a calculated column to store the full path between the current record and its ancestors. Typically this column will be hidden from end users. The PATH function is used to produce a pipe (|) delimited string with the identifiers of all the parents of the current identifier, starting with the oldest and continuing until current. The function requires the input of the table ID and the parent ID. Using the DimEmployee table example, the Path column based on the expression PATH([EmployeeKey], [ParentEmployeeKey]) will produce the following result.



Notice the row for EmployeeKey 18 (Pieter Uittenbogaard). A blank ParentEmployeeKey value means this employee is the root of the hierarchy – in fact he is the Group Manager (there is no higher position). Next, notice EmployeeKey 1 (Kim Abercrombie) who has a ParentEmployeeKey value of 18. She reports to Pieter Uittenbogaard, and is a Region Manager. Next, notice the row for EmployeeKey 6 (Yoichiro Okada). He reports to Kim Abercrombie and is a State Manager. By now it should be clear what the path represents the chain of relationships for each row in the table.


The PATHITEM function is used to extract an item from the path at a particular position. This is useful for naturalizing the parent-child related data into fixed columns, and is necessary if you want to construct a hierarchy to simulate a parent-child relationship in the data model. The PATHITEM function requires a path produced by the PATH function, and the position to return. Positions are counted from left to right.

In the above example the PATHITEM([Path], 1, 1) will return they value 18 for each row. The second argument, in this case, 1, specifies the type INT. The column Region Manager based on the expression PATHITEM([Path], 2, 1) will produce the following result.




Notice the State Manager column returns the second item from the Path column. Notice in the row for Pieter Uittenbogaard the request for an item that does not exist in the path will return BLANK.


When the item is a key, it is useful to perform a lookup to retrieve the employee name. The DAX expression used in the Region Manager column is updated to LOOKUPVALUE([EmployeeName], [EmployeeKey], PATHITEM([Path], 2, 1)), and it produces the following result.




This calculation can be adapted to produce the Group Manager (position 1), State Manager (position 3) and Store Manager (position 4).



These columns can then be used to create a hierarchy named Sales Organization in this example. Notice the key columns and the Path column are hidden. These do not need to be surfaced to the model consumers.



The following PivotTable report uses the Sales Organization to report Vacation Hours.




The Sales Organization hierarchy reveals blank members that represent the values for parent member. For example, the 80 Vacation Hours in cell B3 are Pieter Uittenbogaard’s. To provide meaningful labels to the blank values, the DAX expression can be adapted to test for a blank value returned from the ITEMPATH function, and where it is blank, the value can be expressed as the last item in the path. The PATHITEMREVERSE is helpful here. This function returns the item at the specified position from a path, and positions are counted backwards from right to left. The request for the item at position 1 will provide the lowest (leaf) item.


The Region Manager column is updated to:

IF(ISBLANK(PATHITEM([Path], 2, 1)), “(“ & LOOKUPVALUE([EmployeeName], [EmployeeKey], PATHITEMREVERSE([Path], 1, 1)) & “ data)”, LOOKUPVALUE([EmployeeName], [EmployeeKey], PATHITEM([Path], 2, 1))).

The State Manager and Store Manager columns are similarly updated, and it produces the following result.



Notable there are no more blank values. A refresh of the PivotTable report reveals the following.



Notice cells B3 and B6 which now meaningfully label the parent member.

Finally, and for completeness, there are two additional DAX functions to support working with self-referencing relationships. They are the PATHLENGTH function which returns the number of parents to the specified item in a given path result, including self, and the PATHCONTAINS function which returns TRUE if a specified item exists within the specified path.

# Sample Formulas

Here are some sample formulas meant to illustrate how DAX formulas might be used to address specific business problems. By no means is list meant to be complete, but simply to illustrate specific scenarios. All of these formulas will work with the Contoso sample database, once you have defined a simple measure named Sales using this formula: =SUM(FactSales[SalesAmount]). Many of these samples are formulas that have already been described in this document.

## Calculated Columns

Formulas in calculated columns aren’t conceptually different from formulas in Excel. DAX does add some new functions, especially in the areas of aggregation and getting data from related tables.

|  |  |
| --- | --- |
| **Sample Formula** | **Comments** |
| =FactSales[SalesQuantity] \* FactSales[UnitCost] | Same formula as in Excel |
| =RELATED(DimProduct[Size]) | Get value from related table |
| =FactSales[SalesQuantity] \* RELATED(DimProduct[UnitCost]) | Get part of calculation from other table |
| =SUMX(RELATEDTABLE(FactSales),FactSales[SalesAmount]) | Sum over related rows in other table |
| =COUNTROWS(RELATEDTABLE(FactSales)) | Count related rows in other table |
| =DimProduct[UnitCost] /  AVERAGEX(ALL(DimProduct),DimProduct[UnitCost]) | Ratio of this product’s unit cost to the average unit cost over all the products |

## Measures

Formulas in measures are conceptually different from anything in Excel because the formula will be evaluated many times using a different context for each evaluation. It can be challenging to anticipate the layout of the PivotTables in which the formula will eventually be evaluated.

|  |  |
| --- | --- |
| **Sample Formula** | **Comments** |
| =SUM(FactSales[SalesAmount]) | Simple aggregation can always be sliced |
| =CALCULATE(SUM(FactSales[SalesAmount]),  DimChannel[ChannelName]="Store") | Set context, then evaluate expression |
| =CALCULATE([Sales],  DimChannel[ChannelName]="Store") | Set context, then evaluate measure that is a simple aggregation |
| =[Sales] (DimChannel[ChannelName]="Store") | Shorthand for CALCULATE (measure) |
| =[Sales] - CALCULATE([Sales],PREVIOUSYEAR(DimDate[DateKey])) | Growth of [Sales] from last year |
| =[Sales] - [Sales] (PREVIOUSYEAR(DimDate[DateKey])) | Same calc using shorthand syntax |
| =[Sales]/[Sales] (ALL(DimProduct)) | Ratio to sales of all products |
| =TOTALQTD([Sales],DimDate[Datekey]) | QTD Sales |
| =SUMX(VALUES(DimStore[StoreKey]),  SUMX(VALUES(DimProduct[ProductKey]),  CALCULATE(SUM(FactInventory[OnHandQuantity]),  LASTNONBLANK(  DATESBETWEEN(  DimDate[Datekey],BLANK(),MAX(DimDate[Datekey])),  CALCULATE(SUM(FactInventory[OnHandQuantity])))))) | Nested aggregation across store and product to find inventory quantity based on last inventory taken for period up through current context |

# DAX Query

DAX Query is a new capability of DAX added in the SQL Server 2012 release. It allows the user (or client application) to retrieve data defined by a table expression from the tabular model. With an understanding of how to create a table expression you are well on your way to writing your own table queries.

Note that table queries cannot be run in PowerPivot. Table queries can only be executed against a tabular model deployed either to SharePoint (PowerPivot) or to a tabular instance of Analysis Services. The table query can be written and executed within SQL Server Management Studio, or executed programmatically by an application. Note, Power View (the new report authoring tool delivered in SQL Server 2012) dynamically constructs and sends table queries to the model.


Model developers may find it helpful to test table queries in SQL Server Management Studio, and then embed the results into their model calculations.

In its most basic form, a table query is expressed as EVALUATE <TableExpression>. TableExpression is simply a table in the model, or any expression that returns a table. It is possible to extend this with clauses to define temporary measures (for use during the query execution) and an ORDER BY clause.


For further information on DAX Table Queries, refer to the TechNet topic [DAX Table Queries](http://technet.microsoft.com/en-us/library/gg492201(SQL.110).aspx).

The following examples provide simple and increasingly sophisticated uses of table queries. (The queries in this paper have been executed in SQL Server Management Studio.)


The first example is a simple table query expression to query the Store table.




This next example uses the FILTER function to filter the rows of the table with an expression. Any valid table expression can be evaluated to produce a query result.




In the following example, the expression uses the CROSSJOIN function to perform a cross join of all Store and Product rows, and then returns a filtered result based on the expression.




This example uses the CROSSJOIN function to cross join the result of two VALUES functions. This way, only the Store table’s Continent column and the Product table’s Product table are returned in the cross joined result. The result of the cross join is filtered by the expression, and then then ADDCOLUMNS function is used to add the Sales measure as a column to the table with the alias of “Total Sales”, and the measure will be evaluated for each row in this table.




This example uses the GENERATE function in combination with the VALUES and TOPN function. The result is each Continent and its top five products by sales. For each row in the first argument, the GENERATE function will execute the function in the second argument.




This example uses the SUMMARIZE function based on the Sales table to “group by” Category and Year, and then produces a summary using the Sales measure aliased as “Total Sales”. The SUMMARIZE function returns a summary table for the requested totals over a set of groups. It can help prepare data for sophisticated calculations. For those readers familiar with T-SQL SELECT statement, this is the equivalent of writing a query using the GROUP BY clause. Notice you do not need to define the relationships between tables when using SUMMARIZE because the relationship is defined in the model.



This example is a variation of the previous example, and includes an ORDER BY clause.



This final example defines a measure on the Sales table named Profit that is then used in the table query. Note the measure exists only for the duration of the table query and are not stored in the data model.



# Additional Resources

This paper introduced many of the fundamental concepts and functions included in the DAX formula language. DAX, however, has immense capabilities in performing highly advanced dynamic calculations that are beyond the scope of what can be described here.

There are many additional resources you can use to learn about DAX formulas and how they can be used effectively in your tabular model solutions.

**Information resources provided and maintained by Microsoft:**

[Books Online for SQL Server 2012](http://go.microsoft.com/fwlink/?LinkID=181772&clcid=0x409) at <http://go.microsoft.com/fwlink/?LinkID=181772&clcid=0x409>.

[Data Analysis Expressions (DAX Reference)](http://go.microsoft.com/fwlink/?LinkID=181772&clcid=0x409) on MSDN at <http://go.microsoft.com/fwlink/?LinkID=181772&clcid=0x409>.

The [Analysis Services and PowerPivot Team Blog](http://go.microsoft.com/fwlink/?LinkID=220949&clcid=0x409) at (<http://go.microsoft.com/fwlink/?LinkID=220949&clcid=0x409>) provides information, tips, news and announcements about SQL Server 2012 Analysis Services (SSAS) Release Candidate 0 (RC 0) and PowerPivot.

The [DAX Resource Center Wiki](file:///C:\UserEducation\DenaliSamples\RC0\DAX%20Resource%20Center%20Wiki) at (<http://go.microsoft.com/fwlink/?LinkID=220966&clcid=0x409>) provides both internal and external information on DAX, including numerous DAX solutions submitted by leading Business Intelligence professionals.

Microsoft PowerPivot for Excel 2010: Give Your Data Meaning published by Microsoft Press at <http://www.microsoft.com/learning/en/us/Book.aspx?ID=14569&locale=en-us>.

The [Tabular Modeling (Adventure Works Tutorial)](http://msdn.microsoft.com/en-us/library/hh231691(v=SQL.110).aspx) at <http://msdn.microsoft.com/en-us/library/hh231691(v=SQL.110).aspx> provides step-by-step instructions on how to create a tabular model project in SSDT that includes many calculations in calculated columns, measures, and row filters. For most formulas, a description about what the formula is meant to do is provided.

**Information and resources provided by BI professionals outside of Microsoft:**

<http://www.powerpivotpro.com/>

<http://sqlblog.com/blogs/alberto_ferrari/default.aspx>

<http://sqlblog.com/blogs/marco_russo/>

<http://cwebbbi.wordpress.com/>

<http://paultebraak.wordpress.com/>

<http://www.bp-msbi.com/>

<http://prologika.com/CS/blogs/blog/default.aspx>

<http://www.powerpivotblog.nl/>